mirror of
https://github.com/9ParsonsB/Pulsar.git
synced 2025-04-05 01:29:38 -04:00
325 lines
12 KiB
Plaintext
325 lines
12 KiB
Plaintext
; Script generated by the Inno Setup Script Wizard.
|
|
; SEE THE DOCUMENTATION FOR DETAILS ON CREATING INNO SETUP SCRIPT FILES!
|
|
|
|
#define MyAppName "Elite Observatory"
|
|
#define MyAppPublisher "Jonathan Miller"
|
|
#define MyAppURL "https://github.com/xjph/ObservatoryCore"
|
|
#define MyAppExeName "ObservatoryCore.exe"
|
|
#define MyAppVersion GetVersionNumbersString('..\ObservatoryCore\bin\Release\net5.0\publish\framework-dependent\ObservatoryCore.exe')
|
|
|
|
[Setup]
|
|
; NOTE: The value of AppId uniquely identifies this application. Do not use the same AppId value in installers for other applications.
|
|
; (To generate a new GUID, click Tools | Generate GUID inside the IDE.)
|
|
AppId={{025F6049-430E-45D9-833E-30F0F5D998F5}
|
|
AppName={#MyAppName}
|
|
AppVersion={#MyAppVersion}
|
|
;AppVerName={#MyAppName} {#MyAppVersion}
|
|
AppPublisher={#MyAppPublisher}
|
|
AppPublisherURL={#MyAppURL}
|
|
AppSupportURL={#MyAppURL}
|
|
AppUpdatesURL={#MyAppURL}
|
|
DefaultDirName={autopf}\{#MyAppName}
|
|
DefaultGroupName={#MyAppName}
|
|
AllowNoIcons=yes
|
|
LicenseFile=C:\Users\Xjph\Source\Repos\MIT.txt
|
|
; Uncomment the following line to run in non administrative install mode (install for current user only.)
|
|
;PrivilegesRequired=lowest
|
|
PrivilegesRequiredOverridesAllowed=dialog
|
|
OutputDir=.
|
|
OutputBaseFilename=ObservatorySetup
|
|
SetupIconFile=..\ObservatoryCore\Assets\EOCIcon-Presized.ico
|
|
Compression=lzma
|
|
SolidCompression=yes
|
|
WizardStyle=modern
|
|
ArchitecturesInstallIn64BitMode=x64
|
|
|
|
[Languages]
|
|
Name: "english"; MessagesFile: "compiler:Default.isl"
|
|
|
|
[Tasks]
|
|
Name: "desktopicon"; Description: "{cm:CreateDesktopIcon}"; GroupDescription: "{cm:AdditionalIcons}"; Flags: unchecked
|
|
|
|
[Types]
|
|
Name: "Full"; Description: "Full installation"
|
|
Name: "Custom"; Description: "Custom installation"; Flags: iscustom
|
|
|
|
[CustomMessages]
|
|
TelegramDescription=Telegram: Plugin for sending notifications via Telegram instant messages.%nProvided by Matt-G (mgraham-dev).
|
|
|
|
[Components]
|
|
Name: "Core"; Description: "Core Elite Observatory Application"; Flags: fixed; Types: Full Custom
|
|
Name: "Plugins"; Description: "Optional Observatory Plugins"; Types: Full
|
|
Name: "Plugins\Explorer"; Description: "Explorer: Plugin for finding interesting objects while exploring."; Types: Full
|
|
Name: "Plugins\Botanist"; Description: "Botanist: Plugin for tracking surface biological signals scanned while on foot."; Types: Full
|
|
Name: "Plugins\Telegram"; Description: "{cm:TelegramDescription}"; Types: Full
|
|
|
|
[Dirs]
|
|
Name: "{app}\plugins"; Permissions: users-modify
|
|
|
|
[Files]
|
|
Source: "..\ObservatoryCore\bin\Release\net5.0\publish\framework-dependent\{#MyAppExeName}"; DestDir: "{app}"; Flags: ignoreversion
|
|
Source: "..\ObservatoryCore\bin\Release\net5.0\publish\framework-dependent\*"; Excludes: "\plugins\*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs createallsubdirs
|
|
Source: "..\ObservatoryCore\bin\Release\net5.0\plugins\ObservatoryExplorer.dll"; DestDir: "{app}\plugins"; Components: Plugins\Explorer
|
|
Source: "..\ObservatoryCore\bin\Release\net5.0\plugins\deps\lua54.dll"; DestDir: "{app}\plugins\deps"; Components: Plugins\Explorer
|
|
Source: "..\ObservatoryCore\bin\Release\net5.0\plugins\deps\KeraLua.dll"; DestDir: "{app}\plugins\deps"; Components: Plugins\Explorer
|
|
Source: "..\ObservatoryCore\bin\Release\net5.0\plugins\deps\NLua.dll"; DestDir: "{app}\plugins\deps"; Components: Plugins\Explorer
|
|
Source: "..\ObservatoryCore\bin\Release\net5.0\plugins\ObservatoryBotanist.dll"; DestDir: "{app}\plugins"; Components: Plugins\Botanist
|
|
Source: "..\ObservatoryCore\bin\Release\net5.0\plugins\ObservatoryTelegram.dll"; DestDir: "{app}\plugins"; Components: Plugins\Telegram
|
|
Source: ".\netcorecheck.exe"; Flags: dontcopy noencryption
|
|
Source: ".\netcorecheck_x64.exe"; Flags: dontcopy noencryption
|
|
|
|
[Icons]
|
|
Name: "{group}\{#MyAppName}"; Filename: "{app}\{#MyAppExeName}"
|
|
Name: "{autodesktop}\{#MyAppName}"; Filename: "{app}\{#MyAppExeName}"; Tasks: desktopicon
|
|
|
|
[Run]
|
|
Filename: "{app}\{#MyAppExeName}"; Description: "{cm:LaunchProgram,{#StringChange(MyAppName, '&', '&&')}}"; Flags: nowait postinstall skipifsilent
|
|
|
|
[Code]
|
|
|
|
type
|
|
TDependency_Entry = record
|
|
Filename: String;
|
|
Parameters: String;
|
|
Title: String;
|
|
URL: String;
|
|
Checksum: String;
|
|
ForceSuccess: Boolean;
|
|
RestartAfter: Boolean;
|
|
end;
|
|
|
|
var
|
|
Dependency_Memo: String;
|
|
Dependency_List: array of TDependency_Entry;
|
|
Dependency_NeedRestart, Dependency_ForceX86: Boolean;
|
|
Dependency_DownloadPage: TDownloadWizardPage;
|
|
|
|
procedure InitializeWizard;
|
|
begin
|
|
Dependency_DownloadPage := CreateDownloadPage(SetupMessage(msgWizardPreparing), SetupMessage(msgPreparingDesc), nil);
|
|
end;
|
|
|
|
function Dependency_PrepareToInstall(var NeedsRestart: Boolean): String;
|
|
var
|
|
DependencyCount, DependencyIndex, ResultCode: Integer;
|
|
Retry: Boolean;
|
|
TempValue: String;
|
|
begin
|
|
DependencyCount := GetArrayLength(Dependency_List);
|
|
|
|
if DependencyCount > 0 then begin
|
|
Dependency_DownloadPage.Show;
|
|
|
|
for DependencyIndex := 0 to DependencyCount - 1 do begin
|
|
if Dependency_List[DependencyIndex].URL <> '' then begin
|
|
Dependency_DownloadPage.Clear;
|
|
Dependency_DownloadPage.Add(Dependency_List[DependencyIndex].URL, Dependency_List[DependencyIndex].Filename, Dependency_List[DependencyIndex].Checksum);
|
|
|
|
Retry := True;
|
|
while Retry do begin
|
|
Retry := False;
|
|
|
|
try
|
|
Dependency_DownloadPage.Download;
|
|
except
|
|
if Dependency_DownloadPage.AbortedByUser then begin
|
|
Result := Dependency_List[DependencyIndex].Title;
|
|
DependencyIndex := DependencyCount;
|
|
end else begin
|
|
case SuppressibleMsgBox(AddPeriod(GetExceptionMessage), mbError, MB_ABORTRETRYIGNORE, IDIGNORE) of
|
|
IDABORT: begin
|
|
Result := Dependency_List[DependencyIndex].Title;
|
|
DependencyIndex := DependencyCount;
|
|
end;
|
|
IDRETRY: begin
|
|
Retry := True;
|
|
end;
|
|
end;
|
|
end;
|
|
end;
|
|
end;
|
|
end;
|
|
end;
|
|
|
|
if Result = '' then begin
|
|
for DependencyIndex := 0 to DependencyCount - 1 do begin
|
|
Dependency_DownloadPage.SetText(Dependency_List[DependencyIndex].Title, '');
|
|
Dependency_DownloadPage.SetProgress(DependencyIndex + 1, DependencyCount + 1);
|
|
|
|
while True do begin
|
|
ResultCode := 0;
|
|
if ShellExec('', ExpandConstant('{tmp}{\}') + Dependency_List[DependencyIndex].Filename, Dependency_List[DependencyIndex].Parameters, '', SW_SHOWNORMAL, ewWaitUntilTerminated, ResultCode) then begin
|
|
if Dependency_List[DependencyIndex].RestartAfter then begin
|
|
if DependencyIndex = DependencyCount - 1 then begin
|
|
Dependency_NeedRestart := True;
|
|
end else begin
|
|
NeedsRestart := True;
|
|
Result := Dependency_List[DependencyIndex].Title;
|
|
end;
|
|
break;
|
|
end else if (ResultCode = 0) or Dependency_List[DependencyIndex].ForceSuccess then begin // ERROR_SUCCESS (0)
|
|
break;
|
|
end else if ResultCode = 1641 then begin // ERROR_SUCCESS_REBOOT_INITIATED (1641)
|
|
NeedsRestart := True;
|
|
Result := Dependency_List[DependencyIndex].Title;
|
|
break;
|
|
end else if ResultCode = 3010 then begin // ERROR_SUCCESS_REBOOT_REQUIRED (3010)
|
|
Dependency_NeedRestart := True;
|
|
break;
|
|
end;
|
|
end;
|
|
|
|
case SuppressibleMsgBox(FmtMessage(SetupMessage(msgErrorFunctionFailed), [Dependency_List[DependencyIndex].Title, IntToStr(ResultCode)]), mbError, MB_ABORTRETRYIGNORE, IDIGNORE) of
|
|
IDABORT: begin
|
|
Result := Dependency_List[DependencyIndex].Title;
|
|
break;
|
|
end;
|
|
IDIGNORE: begin
|
|
break;
|
|
end;
|
|
end;
|
|
end;
|
|
|
|
if Result <> '' then begin
|
|
break;
|
|
end;
|
|
end;
|
|
|
|
if NeedsRestart then begin
|
|
TempValue := '"' + ExpandConstant('{srcexe}') + '" /restart=1 /LANG="' + ExpandConstant('{language}') + '" /DIR="' + WizardDirValue + '" /GROUP="' + WizardGroupValue + '" /TYPE="' + WizardSetupType(False) + '" /COMPONENTS="' + WizardSelectedComponents(False) + '" /TASKS="' + WizardSelectedTasks(False) + '"';
|
|
if WizardNoIcons then begin
|
|
TempValue := TempValue + ' /NOICONS';
|
|
end;
|
|
RegWriteStringValue(HKA, 'SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnce', '{#SetupSetting("AppName")}', TempValue);
|
|
end;
|
|
end;
|
|
|
|
Dependency_DownloadPage.Hide;
|
|
end;
|
|
end;
|
|
|
|
function PrepareToInstall(var NeedsRestart: Boolean): String;
|
|
begin
|
|
Result := Dependency_PrepareToInstall(NeedsRestart);
|
|
end;
|
|
|
|
function NeedRestart: Boolean;
|
|
begin
|
|
Result := Dependency_NeedRestart;
|
|
end;
|
|
|
|
function Dependency_UpdateReadyMemo(const Space, NewLine, MemoUserInfoInfo, MemoDirInfo, MemoTypeInfo, MemoComponentsInfo, MemoGroupInfo, MemoTasksInfo: String): String;
|
|
begin
|
|
Result := '';
|
|
if MemoUserInfoInfo <> '' then begin
|
|
Result := Result + MemoUserInfoInfo + Newline + NewLine;
|
|
end;
|
|
if MemoDirInfo <> '' then begin
|
|
Result := Result + MemoDirInfo + Newline + NewLine;
|
|
end;
|
|
if MemoTypeInfo <> '' then begin
|
|
Result := Result + MemoTypeInfo + Newline + NewLine;
|
|
end;
|
|
if MemoComponentsInfo <> '' then begin
|
|
Result := Result + MemoComponentsInfo + Newline + NewLine;
|
|
end;
|
|
if MemoGroupInfo <> '' then begin
|
|
Result := Result + MemoGroupInfo + Newline + NewLine;
|
|
end;
|
|
if MemoTasksInfo <> '' then begin
|
|
Result := Result + MemoTasksInfo;
|
|
end;
|
|
|
|
if Dependency_Memo <> '' then begin
|
|
if MemoTasksInfo = '' then begin
|
|
Result := Result + SetupMessage(msgReadyMemoTasks);
|
|
end;
|
|
Result := Result + FmtMessage(Dependency_Memo, [Space]);
|
|
end;
|
|
end;
|
|
|
|
function UpdateReadyMemo(const Space, NewLine, MemoUserInfoInfo, MemoDirInfo, MemoTypeInfo, MemoComponentsInfo, MemoGroupInfo, MemoTasksInfo: String): String;
|
|
begin
|
|
Result := Dependency_UpdateReadyMemo(Space, NewLine, MemoUserInfoInfo, MemoDirInfo, MemoTypeInfo, MemoComponentsInfo, MemoGroupInfo, MemoTasksInfo);
|
|
end;
|
|
|
|
function Dependency_IsX64: Boolean;
|
|
begin
|
|
Result := not Dependency_ForceX86 and Is64BitInstallMode;
|
|
end;
|
|
|
|
function Dependency_String(const x86, x64: String): String;
|
|
begin
|
|
if Dependency_IsX64 then begin
|
|
Result := x64;
|
|
end else begin
|
|
Result := x86;
|
|
end;
|
|
end;
|
|
|
|
function Dependency_ArchSuffix: String;
|
|
begin
|
|
Result := Dependency_String('', '_x64');
|
|
end;
|
|
|
|
function Dependency_ArchTitle: String;
|
|
begin
|
|
Result := Dependency_String(' (x86)', ' (x64)');
|
|
end;
|
|
|
|
function Dependency_IsNetCoreInstalled(const Version: String): Boolean;
|
|
var
|
|
ResultCode: Integer;
|
|
begin
|
|
// source code: https://github.com/dotnet/deployment-tools/tree/master/src/clickonce/native/projects/NetCoreCheck
|
|
if not FileExists(ExpandConstant('{tmp}{\}') + 'netcorecheck' + Dependency_ArchSuffix + '.exe') then begin
|
|
ExtractTemporaryFile('netcorecheck' + Dependency_ArchSuffix + '.exe');
|
|
end;
|
|
Result := ShellExec('', ExpandConstant('{tmp}{\}') + 'netcorecheck' + Dependency_ArchSuffix + '.exe', Version, '', SW_HIDE, ewWaitUntilTerminated, ResultCode) and (ResultCode = 0);
|
|
end;
|
|
|
|
procedure Dependency_Add(const Filename, Parameters, Title, URL, Checksum: String; const ForceSuccess, RestartAfter: Boolean);
|
|
var
|
|
Dependency: TDependency_Entry;
|
|
DependencyCount: Integer;
|
|
begin
|
|
Dependency_Memo := Dependency_Memo + #13#10 + '%1' + Title;
|
|
|
|
Dependency.Filename := Filename;
|
|
Dependency.Parameters := Parameters;
|
|
Dependency.Title := Title;
|
|
|
|
if FileExists(ExpandConstant('{tmp}{\}') + Filename) then begin
|
|
Dependency.URL := '';
|
|
end else begin
|
|
Dependency.URL := URL;
|
|
end;
|
|
|
|
Dependency.Checksum := Checksum;
|
|
Dependency.ForceSuccess := ForceSuccess;
|
|
Dependency.RestartAfter := RestartAfter;
|
|
|
|
DependencyCount := GetArrayLength(Dependency_List);
|
|
SetArrayLength(Dependency_List, DependencyCount + 1);
|
|
Dependency_List[DependencyCount] := Dependency;
|
|
end;
|
|
|
|
procedure Dependency_AddDotNet50Desktop;
|
|
begin
|
|
// https://dotnet.microsoft.com/download/dotnet/5.0
|
|
if not Dependency_IsNetCoreInstalled('Microsoft.WindowsDesktop.App 5.0.7') then begin
|
|
Dependency_Add('dotnet50desktop' + Dependency_ArchSuffix + '.exe',
|
|
'/lcid ' + IntToStr(GetUILanguage) + ' /passive /norestart',
|
|
'.NET Desktop Runtime 5.0.7' + Dependency_ArchTitle,
|
|
Dependency_String('https://go.microsoft.com/fwlink/?linkid=2166320', 'https://go.microsoft.com/fwlink/?linkid=2166224'),
|
|
'', False, False);
|
|
end;
|
|
end;
|
|
|
|
function InitializeSetup: Boolean;
|
|
begin
|
|
// add the dependencies you need
|
|
Dependency_AddDotNet50Desktop;
|
|
// ...
|
|
Result := true;
|
|
end; |